hu:arduino:micro_sd_card

Micro SD kártyamodul

Micro SD kártyamodul

A modul (Micro SD Card Adapter) egy Micro SD kártyaolvasó modul. A modul az Arduino-val való kommunikációjához SPI buszt használ. A modul csatlakoztatását követően a modulba behelyezett kártya fájlrendszere az Arduino felől elérhető, az írható és/vagy olvasható. Jellemző felhasználása: mérésadatok loggolása.

Az Arduino SPI összefoglalása itt található: Arduino SPI.
Az Aduino-s SPI megoldások összefoglalása itt található: Arduino SPI kommunikáció.

A modulban felhasználásra szánt SD kártyát előzetesen formattálni kell. Az Arduino megbirkózik a FAT16 és FAT32-es formátumokkal is, mindenesetre a FAT16 a támogatott. Az SD kártyán használt fájlnevek esetében a szigorúbb, 8.3 forma érvényes, azaz 8 karakter fájlnév és 3 karakter kiterjesztés. Fontos, hogy a file.write() parancs mindaddig nem ír az SD kártyára, míg az előző írásműveletet vagy a close() vagy a flush() paranccsal le nem zárjuk azt. A legegyszerűbb rögtön az írás után lezárni a nyitott fájlt:

A szoftver megjelenítése

A szoftver megjelenítése

  File dataFile = SD.open(filename, FILE_WRITE);
    if (dataFile) {
    dataFile.println(dataString);
    dataFile.close();
    // print to the serial port too:
    Serial.println(dataString);
  }

Több típusú kártyamodul is létezik a piacon, itt most csak ezt az egyet ismertetem. Ha szükséges, kibővítem a dokumentációt.

A kártyamodul portjait az alábbiak szerint érdemes az Aduino UNO-val vagy Mega-val összekötni:

Micro SDArduino UnoArduino Mega
CSpin 4pin 53
SCKpin 13pin 52
MOSIpin 11pin 51
MISOpin 12pin 50
VCC5V5V
GNDGNDGND

Micro SD kártyamodul bekötése az UNO-n

A Micro SD kártyamodul leírása a Arduino oldalon itt található:

https://www.arduino.cc/en/Reference/SD

A Micro SD kártyamodul könyvtára innen tölthető le: https://github.com/greiman/SdFat

Ugyaninnen a példaprogramok széles választéka is letölthető: https://github.com/greiman/SdFat/tree/master/examples

„SD card datalogger” szoftver megjelenítése

„SD card datalogger” szoftver megjelenítése

/*
  SD card datalogger
 
  This example shows how to log data from three analog sensors
  to an SD card using the SD library.
 
  The circuit:
   analog sensors on analog ins 0, 1, and 2
   SD card attached to SPI bus as follows:
 ** MOSI - pin 11
 ** MISO - pin 12
 ** CLK - pin 13
 ** CS - pin 4 (for MKRZero SD: SDCARD_SS_PIN)
 
  created  24 Nov 2010
  modified 9 Apr 2012
  by Tom Igoe
 
  This example code is in the public domain.
 
*/
 
#include <SPI.h>
#include <SD.h>
 
const int chipSelect = 4;
 
void setup() {
  // Open serial communications and wait for port to open:
  Serial.begin(9600);
  while (!Serial) {
    ; // wait for serial port to connect. Needed for native USB port only
  }
 
 
  Serial.print("Initializing SD card...");
 
  // see if the card is present and can be initialized:
  if (!SD.begin(chipSelect)) {
    Serial.println("Card failed, or not present");
    // don't do anything more:
    while (1);
  }
  Serial.println("card initialized.");
}
 
void loop() {
  // make a string for assembling the data to log:
  String dataString = "";
 
  // read three sensors and append to the string:
  for (int analogPin = 0; analogPin < 3; analogPin++) {
    int sensor = analogRead(analogPin);
    dataString += String(sensor);
    if (analogPin < 2) {
      dataString += ",";
    }
  }
 
  // open the file. note that only one file can be open at a time,
  // so you have to close this one before opening another.
  File dataFile = SD.open("datalog.txt", FILE_WRITE);
 
  // if the file is available, write to it:
  if (dataFile) {
    dataFile.println(dataString);
    dataFile.close();
    // print to the serial port too:
    Serial.println(dataString);
  }
  // if the file isn't open, pop up an error:
  else {
    Serial.println("error opening datalog.txt");
  }
}
  • hu/arduino/micro_sd_card.txt
  • 2022/04/21 15:02
  • ()